Paul Mundt | 336f1d3 | 2008-05-19 19:39:33 +0900 | [diff] [blame] | 1 | /* |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 2 | * Copyright (C) 1999, 2000, 2002 Niibe Yutaka |
Paul Mundt | 336f1d3 | 2008-05-19 19:39:33 +0900 | [diff] [blame] | 3 | * Copyright (C) 2003 - 2008 Paul Mundt |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 4 | * |
| 5 | * This file is subject to the terms and conditions of the GNU General Public |
| 6 | * License. See the file "COPYING" in the main directory of this archive |
| 7 | * for more details. |
| 8 | * |
| 9 | */ |
| 10 | |
| 11 | ! NOTE: |
| 12 | ! GNU as (as of 2.9.1) changes bf/s into bt/s and bra, when the address |
| 13 | ! to be jumped is too far, but it causes illegal slot exception. |
| 14 | |
| 15 | /* |
| 16 | * entry.S contains the system-call and fault low-level handling routines. |
| 17 | * This also contains the timer-interrupt handler, as well as all interrupts |
| 18 | * and faults that can result in a task-switch. |
| 19 | * |
| 20 | * NOTE: This code handles signal-recognition, which happens every time |
| 21 | * after a timer-interrupt and after each system call. |
| 22 | * |
| 23 | * NOTE: This code uses a convention that instructions in the delay slot |
| 24 | * of a transfer-control instruction are indented by an extra space, thus: |
| 25 | * |
| 26 | * jmp @k0 ! control-transfer instruction |
| 27 | * ldc k1, ssr ! delay slot |
| 28 | * |
| 29 | * Stack layout in 'ret_from_syscall': |
| 30 | * ptrace needs to have all regs on the stack. |
| 31 | * if the order here is changed, it needs to be |
| 32 | * updated in ptrace.c and ptrace.h |
| 33 | * |
| 34 | * r0 |
| 35 | * ... |
| 36 | * r15 = stack pointer |
| 37 | * spc |
| 38 | * pr |
| 39 | * ssr |
| 40 | * gbr |
| 41 | * mach |
| 42 | * macl |
| 43 | * syscall # |
| 44 | * |
| 45 | */ |
Matt Fleming | cafb0dd | 2009-08-02 22:40:11 +0100 | [diff] [blame] | 46 | #include <asm/dwarf.h> |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 47 | |
| 48 | #if defined(CONFIG_PREEMPT) |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 49 | # define preempt_stop() cli ; TRACE_IRQS_OFF |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 50 | #else |
| 51 | # define preempt_stop() |
| 52 | # define resume_kernel __restore_all |
| 53 | #endif |
| 54 | |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 55 | |
| 56 | .align 2 |
| 57 | ENTRY(exception_error) |
| 58 | ! |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 59 | TRACE_IRQS_ON |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 60 | sti |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 61 | mov.l 1f, r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 62 | jmp @r0 |
| 63 | nop |
| 64 | |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 65 | .align 2 |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 66 | 1: .long do_exception_error |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 67 | |
| 68 | .align 2 |
| 69 | ret_from_exception: |
Matt Fleming | cafb0dd | 2009-08-02 22:40:11 +0100 | [diff] [blame] | 70 | CFI_STARTPROC simple |
| 71 | CFI_DEF_CFA r14, 0 |
| 72 | CFI_REL_OFFSET 17, 64 |
Matt Fleming | 1426982 | 2010-01-27 20:05:20 +0000 | [diff] [blame] | 73 | CFI_REL_OFFSET 15, 60 |
Matt Fleming | cafb0dd | 2009-08-02 22:40:11 +0100 | [diff] [blame] | 74 | CFI_REL_OFFSET 14, 56 |
Matt Fleming | 1426982 | 2010-01-27 20:05:20 +0000 | [diff] [blame] | 75 | CFI_REL_OFFSET 13, 52 |
| 76 | CFI_REL_OFFSET 12, 48 |
| 77 | CFI_REL_OFFSET 11, 44 |
| 78 | CFI_REL_OFFSET 10, 40 |
| 79 | CFI_REL_OFFSET 9, 36 |
| 80 | CFI_REL_OFFSET 8, 32 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 81 | preempt_stop() |
| 82 | ENTRY(ret_from_irq) |
| 83 | ! |
| 84 | mov #OFF_SR, r0 |
| 85 | mov.l @(r0,r15), r0 ! get status register |
| 86 | shll r0 |
| 87 | shll r0 ! kernel space? |
| 88 | get_current_thread_info r8, r0 |
| 89 | bt resume_kernel ! Yes, it's from kernel, go back soon |
| 90 | |
| 91 | #ifdef CONFIG_PREEMPT |
| 92 | bra resume_userspace |
| 93 | nop |
| 94 | ENTRY(resume_kernel) |
Carmelo Amoroso | 323b8c4 | 2008-09-05 14:42:16 +0900 | [diff] [blame] | 95 | cli |
Matt Fleming | f3a8308 | 2009-08-18 11:35:09 +0900 | [diff] [blame] | 96 | TRACE_IRQS_OFF |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 97 | mov.l @(TI_PRE_COUNT,r8), r0 ! current_thread_info->preempt_count |
| 98 | tst r0, r0 |
| 99 | bf noresched |
| 100 | need_resched: |
| 101 | mov.l @(TI_FLAGS,r8), r0 ! current_thread_info->flags |
| 102 | tst #_TIF_NEED_RESCHED, r0 ! need_resched set? |
| 103 | bt noresched |
| 104 | |
| 105 | mov #OFF_SR, r0 |
| 106 | mov.l @(r0,r15), r0 ! get status register |
Stuart Menefy | fea966f | 2009-08-24 17:09:53 +0900 | [diff] [blame] | 107 | shlr r0 |
| 108 | and #(0xf0>>1), r0 ! interrupts off (exception path)? |
| 109 | cmp/eq #(0xf0>>1), r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 110 | bt noresched |
Paul Mundt | afbfb52 | 2006-12-04 18:17:28 +0900 | [diff] [blame] | 111 | mov.l 3f, r0 |
Carmelo Amoroso | 323b8c4 | 2008-09-05 14:42:16 +0900 | [diff] [blame] | 112 | jsr @r0 ! call preempt_schedule_irq |
Paul Mundt | afbfb52 | 2006-12-04 18:17:28 +0900 | [diff] [blame] | 113 | nop |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 114 | bra need_resched |
| 115 | nop |
Paul Mundt | afbfb52 | 2006-12-04 18:17:28 +0900 | [diff] [blame] | 116 | |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 117 | noresched: |
| 118 | bra __restore_all |
| 119 | nop |
| 120 | |
| 121 | .align 2 |
| 122 | 1: .long PREEMPT_ACTIVE |
| 123 | 2: .long schedule |
Carmelo Amoroso | 323b8c4 | 2008-09-05 14:42:16 +0900 | [diff] [blame] | 124 | 3: .long preempt_schedule_irq |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 125 | #endif |
| 126 | |
| 127 | ENTRY(resume_userspace) |
| 128 | ! r8: current_thread_info |
| 129 | cli |
Paul Mundt | 457b646 | 2009-10-14 15:50:28 +0900 | [diff] [blame] | 130 | TRACE_IRQS_OFF |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 131 | mov.l @(TI_FLAGS,r8), r0 ! current_thread_info->flags |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 132 | tst #(_TIF_WORK_MASK & 0xff), r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 133 | bt/s __restore_all |
| 134 | tst #_TIF_NEED_RESCHED, r0 |
| 135 | |
| 136 | .align 2 |
| 137 | work_pending: |
| 138 | ! r0: current_thread_info->flags |
| 139 | ! r8: current_thread_info |
| 140 | ! t: result of "tst #_TIF_NEED_RESCHED, r0" |
| 141 | bf/s work_resched |
Al Viro | 5e071e2 | 2012-09-18 17:04:37 +0900 | [diff] [blame] | 142 | tst #(_TIF_SIGPENDING | _TIF_NOTIFY_RESUME), r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 143 | work_notifysig: |
| 144 | bt/s __restore_all |
| 145 | mov r15, r4 |
| 146 | mov r12, r5 ! set arg1(save_r0) |
| 147 | mov r0, r6 |
Paul Mundt | 6330c04 | 2012-01-10 16:30:37 +0900 | [diff] [blame] | 148 | sti |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 149 | mov.l 2f, r1 |
| 150 | mov.l 3f, r0 |
| 151 | jmp @r1 |
| 152 | lds r0, pr |
| 153 | work_resched: |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 154 | mov.l 1f, r1 |
| 155 | jsr @r1 ! schedule |
| 156 | nop |
| 157 | cli |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 158 | TRACE_IRQS_OFF |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 159 | ! |
| 160 | mov.l @(TI_FLAGS,r8), r0 ! current_thread_info->flags |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 161 | tst #(_TIF_WORK_MASK & 0xff), r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 162 | bt __restore_all |
| 163 | bra work_pending |
| 164 | tst #_TIF_NEED_RESCHED, r0 |
| 165 | |
| 166 | .align 2 |
| 167 | 1: .long schedule |
| 168 | 2: .long do_notify_resume |
Stuart MENEFY | 0b1689c | 2008-07-17 13:08:40 +0100 | [diff] [blame] | 169 | 3: .long resume_userspace |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 170 | |
| 171 | .align 2 |
| 172 | syscall_exit_work: |
| 173 | ! r0: current_thread_info->flags |
| 174 | ! r8: current_thread_info |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 175 | tst #(_TIF_WORK_SYSCALL_MASK & 0xff), r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 176 | bt/s work_pending |
| 177 | tst #_TIF_NEED_RESCHED, r0 |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 178 | TRACE_IRQS_ON |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 179 | sti |
Yuichi Nakamura | 1322b9d | 2007-11-10 19:21:34 +0900 | [diff] [blame] | 180 | mov r15, r4 |
Paul Mundt | ab99c73 | 2008-07-30 19:55:30 +0900 | [diff] [blame] | 181 | mov.l 8f, r0 ! do_syscall_trace_leave |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 182 | jsr @r0 |
| 183 | nop |
| 184 | bra resume_userspace |
| 185 | nop |
| 186 | |
| 187 | .align 2 |
| 188 | syscall_trace_entry: |
| 189 | ! Yes it is traced. |
Yuichi Nakamura | 1322b9d | 2007-11-10 19:21:34 +0900 | [diff] [blame] | 190 | mov r15, r4 |
Paul Mundt | ab99c73 | 2008-07-30 19:55:30 +0900 | [diff] [blame] | 191 | mov.l 7f, r11 ! Call do_syscall_trace_enter which notifies |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 192 | jsr @r11 ! superior (will chomp R[0-7]) |
| 193 | nop |
Paul Mundt | ab99c73 | 2008-07-30 19:55:30 +0900 | [diff] [blame] | 194 | mov.l r0, @(OFF_R0,r15) ! Save return value |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 195 | ! Reload R0-R4 from kernel stack, where the |
| 196 | ! parent may have modified them using |
| 197 | ! ptrace(POKEUSR). (Note that R0-R2 are |
| 198 | ! used by the system call handler directly |
| 199 | ! from the kernel stack anyway, so don't need |
| 200 | ! to be reloaded here.) This allows the parent |
| 201 | ! to rewrite system calls and args on the fly. |
| 202 | mov.l @(OFF_R4,r15), r4 ! arg0 |
| 203 | mov.l @(OFF_R5,r15), r5 |
| 204 | mov.l @(OFF_R6,r15), r6 |
| 205 | mov.l @(OFF_R7,r15), r7 ! arg3 |
| 206 | mov.l @(OFF_R3,r15), r3 ! syscall_nr |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 207 | ! |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 208 | mov.l 2f, r10 ! Number of syscalls |
| 209 | cmp/hs r10, r3 |
| 210 | bf syscall_call |
| 211 | mov #-ENOSYS, r0 |
| 212 | bra syscall_exit |
| 213 | mov.l r0, @(OFF_R0,r15) ! Return value |
| 214 | |
| 215 | __restore_all: |
Matt Fleming | f3a8308 | 2009-08-18 11:35:09 +0900 | [diff] [blame] | 216 | mov #OFF_SR, r0 |
| 217 | mov.l @(r0,r15), r0 ! get status register |
| 218 | |
| 219 | shlr2 r0 |
| 220 | and #0x3c, r0 |
| 221 | cmp/eq #0x3c, r0 |
| 222 | bt 1f |
| 223 | TRACE_IRQS_ON |
| 224 | bra 2f |
| 225 | nop |
| 226 | 1: |
| 227 | TRACE_IRQS_OFF |
| 228 | 2: |
| 229 | mov.l 3f, r0 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 230 | jmp @r0 |
| 231 | nop |
| 232 | |
| 233 | .align 2 |
Matt Fleming | f3a8308 | 2009-08-18 11:35:09 +0900 | [diff] [blame] | 234 | 3: .long restore_all |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 235 | |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 236 | .align 2 |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 237 | syscall_badsys: ! Bad syscall number |
Hideo Saito | 561c2bc | 2008-05-15 13:30:05 +0900 | [diff] [blame] | 238 | get_current_thread_info r8, r0 |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 239 | mov #-ENOSYS, r0 |
| 240 | bra resume_userspace |
| 241 | mov.l r0, @(OFF_R0,r15) ! Return value |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 242 | |
| 243 | /* |
| 244 | * The main debug trap handler. |
| 245 | * |
| 246 | * r8=TRA (not the trap number!) |
| 247 | * |
| 248 | * Note: This assumes that the trapa value is left in its original |
| 249 | * form (without the shlr2 shift) so the calculation for the jump |
| 250 | * call table offset remains a simple in place mask. |
| 251 | */ |
| 252 | debug_trap: |
| 253 | mov r8, r0 |
| 254 | and #(0xf << 2), r0 |
| 255 | mov.l 1f, r8 |
| 256 | add r0, r8 |
| 257 | mov.l @r8, r8 |
Paul Mundt | 336f1d3 | 2008-05-19 19:39:33 +0900 | [diff] [blame] | 258 | jsr @r8 |
| 259 | nop |
| 260 | bra __restore_all |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 261 | nop |
Matt Fleming | cafb0dd | 2009-08-02 22:40:11 +0100 | [diff] [blame] | 262 | CFI_ENDPROC |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 263 | |
| 264 | .align 2 |
| 265 | 1: .long debug_trap_table |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 266 | |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 267 | /* |
| 268 | * Syscall interface: |
| 269 | * |
| 270 | * Syscall #: R3 |
| 271 | * Arguments #0 to #3: R4--R7 |
| 272 | * Arguments #4 to #6: R0, R1, R2 |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 273 | * TRA: (number of arguments + ABI revision) x 4 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 274 | * |
| 275 | * This code also handles delegating other traps to the BIOS/gdb stub |
| 276 | * according to: |
| 277 | * |
| 278 | * Trap number |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 279 | * (TRA>>2) Purpose |
| 280 | * -------- ------- |
| 281 | * 0x00-0x0f original SH-3/4 syscall ABI (not in general use). |
| 282 | * 0x10-0x1f general SH-3/4 syscall ABI. |
| 283 | * 0x20-0x2f syscall ABI for SH-2 parts. |
| 284 | * 0x30-0x3f debug traps used by the kernel. |
| 285 | * 0x40-0xff Not supported by all parts, so left unhandled. |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 286 | * |
| 287 | * Note: When we're first called, the TRA value must be shifted |
| 288 | * right 2 bits in order to get the value that was used as the "trapa" |
| 289 | * argument. |
| 290 | */ |
| 291 | |
| 292 | .align 2 |
| 293 | .globl ret_from_fork |
| 294 | ret_from_fork: |
| 295 | mov.l 1f, r8 |
| 296 | jsr @r8 |
| 297 | mov r0, r4 |
| 298 | bra syscall_exit |
| 299 | nop |
| 300 | .align 2 |
| 301 | 1: .long schedule_tail |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 302 | |
| 303 | /* |
| 304 | * The poorly named main trapa decode and dispatch routine, for |
| 305 | * system calls and debug traps through their respective jump tables. |
| 306 | */ |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 307 | ENTRY(system_call) |
Matt Fleming | 0b93048 | 2009-08-02 22:33:26 +0100 | [diff] [blame] | 308 | setup_frame_reg |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 309 | #if !defined(CONFIG_CPU_SH2) |
| 310 | mov.l 1f, r9 |
| 311 | mov.l @r9, r8 ! Read from TRA (Trap Address) Register |
| 312 | #endif |
Paul Mundt | ab6e570 | 2008-12-11 18:46:46 +0900 | [diff] [blame] | 313 | |
| 314 | mov #OFF_TRA, r10 |
| 315 | add r15, r10 |
| 316 | mov.l r8, @r10 ! set TRA value to tra |
| 317 | |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 318 | /* |
| 319 | * Check the trap type |
| 320 | */ |
| 321 | mov #((0x20 << 2) - 1), r9 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 322 | cmp/hi r9, r8 |
Paul Mundt | f413d0d | 2006-12-13 17:40:05 +0900 | [diff] [blame] | 323 | bt/s debug_trap ! it's a debug trap.. |
Paul Mundt | ab6e570 | 2008-12-11 18:46:46 +0900 | [diff] [blame] | 324 | nop |
| 325 | |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 326 | TRACE_IRQS_ON |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 327 | sti |
Paul Mundt | afbfb52 | 2006-12-04 18:17:28 +0900 | [diff] [blame] | 328 | |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 329 | ! |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 330 | get_current_thread_info r8, r10 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 331 | mov.l @(TI_FLAGS,r8), r8 |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 332 | mov #(_TIF_WORK_SYSCALL_MASK & 0xff), r10 |
| 333 | mov #(_TIF_WORK_SYSCALL_MASK >> 8), r9 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 334 | tst r10, r8 |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 335 | shll8 r9 |
| 336 | bf syscall_trace_entry |
| 337 | tst r9, r8 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 338 | bf syscall_trace_entry |
| 339 | ! |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 340 | mov.l 2f, r8 ! Number of syscalls |
| 341 | cmp/hs r8, r3 |
| 342 | bt syscall_badsys |
| 343 | ! |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 344 | syscall_call: |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 345 | shll2 r3 ! x4 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 346 | mov.l 3f, r8 ! Load the address of sys_call_table |
Stuart Menefy | e0969e0 | 2006-11-24 13:01:36 +0900 | [diff] [blame] | 347 | add r8, r3 |
| 348 | mov.l @r3, r8 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 349 | jsr @r8 ! jump to specific syscall handler |
| 350 | nop |
| 351 | mov.l @(OFF_R0,r15), r12 ! save r0 |
| 352 | mov.l r0, @(OFF_R0,r15) ! save the return value |
| 353 | ! |
| 354 | syscall_exit: |
| 355 | cli |
Stuart Menefy | fd78a76 | 2009-07-29 23:01:24 +0900 | [diff] [blame] | 356 | TRACE_IRQS_OFF |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 357 | ! |
| 358 | get_current_thread_info r8, r0 |
| 359 | mov.l @(TI_FLAGS,r8), r0 ! current_thread_info->flags |
Matt Fleming | c652d78 | 2009-07-06 20:16:33 +0900 | [diff] [blame] | 360 | tst #(_TIF_ALLWORK_MASK & 0xff), r0 |
| 361 | mov #(_TIF_ALLWORK_MASK >> 8), r1 |
| 362 | bf syscall_exit_work |
| 363 | shlr8 r0 |
| 364 | tst r0, r1 |
Yoshinori Sato | de39840 | 2006-11-05 16:15:19 +0900 | [diff] [blame] | 365 | bf syscall_exit_work |
| 366 | bra __restore_all |
| 367 | nop |
| 368 | .align 2 |
| 369 | #if !defined(CONFIG_CPU_SH2) |
| 370 | 1: .long TRA |
| 371 | #endif |
| 372 | 2: .long NR_syscalls |
| 373 | 3: .long sys_call_table |
Paul Mundt | ab99c73 | 2008-07-30 19:55:30 +0900 | [diff] [blame] | 374 | 7: .long do_syscall_trace_enter |
| 375 | 8: .long do_syscall_trace_leave |